This small addon mod is a backport of the Crafttweaker Blueprint recipe support that exists in modern versions of Immersive Engineering.

This mod is designed for modpackers using the 1.7.10 version of minecraft to allow them to customize blueprints using zenscript (see below)

To add a blueprint

mods.immersiveengineering.Blueprint.addRecipe(String category, IItemStack output, IIngredient[] inputs);

To remove a blueprint

mods.immersiveengineering.Blueprint.removeRecipe(IItemStack output);

Additionally, this addon allows users to modify the Engineer's Manual by adding/removing entries and pages

To remove an entry

mods.immersiveengineering.Manual.removeEntry(String name);

To remove a specific page

mods.immersiveengineering.Manual.removePage(String name, int pageNum);

To add a page
mods.immersiveengineering.Manual.addTextPage(String name, String text, @Optional String category, @Optional int pageNum);

EXAMPLE SCRIPT

// add a new blueprint and recipe using that blueprint

// NOTE: this blueprint will be unobtainable in survival. You must create your own recipe.

mods.immersiveengineering.Blueprint.addRecipe("vanillaItems", <minecraft:iron_bars>*4, [<ore:stickIron>, <ore:stickIron>]);

game.setLocalization("desc.ImmersiveEngineering.info.blueprint.vanillaItems", "Vanilla Items");

// remove the entire entry about graphite

mods.immersiveengineering.Manual.removeEntry("graphite");

// remove the last seven pages of the biodiesel category

var removePages = [7, 6, 5, 4, 3, 2, 1] as int[];

for i in removePages{

mods.immersiveengineering.Manual.removePage("biodiesel", i);

}

// Add a new page to replace the ones that were removed

game.setLocalization("ie.manual.entry.biodieselTest", "Biodiesel is basically useless. Don't listen to the wiki");

mods.immersiveengineering.Manual.addTextPage("biodiesel", "biodieselTest", 1);

// Add a new category, an entry and three pages

game.setLocalization("ie.manual.category.gregtech.name", "Greg Tech");

game.setLocalization("ie.manual.entry.ochem.name", "Organic Chemistry");

game.setLocalization("ie.manual.entry.ochem.subtext", "");

game.setLocalization("ie.manual.entry.ochem0", "this is the first page");

game.setLocalization("ie.manual.entry.ochem1", "this is the second page");

game.setLocalization("ie.manual.entry.ochem2", "this is the third page");

mods.immersiveengineering.Manual.addTextPage("ochem", "ochem2", "gregtech"); // create a new category (gregtech) and entry (ochem)

mods.immersiveengineering.Manual.addTextPage("ochem", "ochem0"); // default insert as first page

mods.immersiveengineering.Manual.addTextPage("ochem", "ochem1", 1); // insert at page index 1

No files available for download.

Immersive Engineering Blueprint Tweaker

More from facetorched